BuzzKick (1tracker)

The UI changes is just different font.bmp file, it allows to customize the looks (along with the .cfg file). Tried to do something more comfortable to work with on my PC. Tracker code itself had no changes yet, although yes, I want to eventually add some things from SNESGSS interface, that also had pattern-less approach.

Sound generation loop from this engine, that closely matches SpecialFX:

soundLoop

    ld a,3                ;7 - this part is just 62t delay, to align the (empty) loop to 168t, allowing to have lowest E note
    dec a                ;4
    jr nz,$-1            ;7/12=50t
    jr $+2            ;12

    dec d                ;4 - channel 1 8-bit counter
    jp nz,.ch2            ;10

.ch1freq=$+1
    ld d,0            ;7 - reload counter

.ch1delay1=$+1
    ld a,0                ;7 - first variable delay, that is like bottom of a pin, it gets changed by the decay envelope
    dec a                ;4
    jr nz,$-1            ;7/12

.ch1out=$+1
    ld a,0                ;7  - output a set bit (or reset, if the channel is muted)
    out (#fe),a            ;11

.ch1delay2=$+1
    ld a,0                ;7 - second variable delay, that is top of a pin
    dec a                ;4
    jr nz,$-1            ;7/12

    out (#fe),a            ;11 - reset output, pin is ended

.ch2

    ld a,3                ;7 - the same for the second channel
    dec a                ;4
    jr nz,$-1            ;7/12=50t
    jr $+2            ;12

    dec e                ;4
    jp nz,.loop            ;10

.ch2freq=$+1
    ld e,0                ;7

.ch2delay1=$+1
    ld a,0                ;7
    dec a                ;4
    jr nz,$-1            ;7/12

.ch2out=$+1
    ld a,0                ;7
    out (#fe),a            ;11

.ch2delay2=$+1
    ld a,0                ;7
    dec a                ;4
    jr nz,$-1            ;7/12

    out (#fe),a            ;11

.loop

    dec b                ;4
    jr nz,soundLoop        ;7/12=168t

The weird part of PFM engines of this kind, with separate pins (not combined like QChan or Octode), that I don't really understand, is that they output both 0 and 1 parts of a pin with corresponding delay, not just 1. If you omit the 0 part with its delay, cross-detune gets just horrible, even with two channels.

Unfortunately, combining the pins gives different timbre. Not sure how to describe it, and I didn't analyze it, but it feels like it has different harmonics. Engines of this kind, with separate pins, were underdeveloped in modern era. In the past it was FuzzClick, the Code Masters engine (Whittaker's?), Tim Follin's, the one from Dark Fusion, etc, and currently there is next to none (just original Beep Tracker). Worth experimenting, I think.

The overall delay1+delay2 always equals to the same time, so width of a pin (0 and 1 parts) is always the same. Initial values are tricky for FuzzClick, delay1 is the frequency counter value shifted >>2 or >>3 (for channel 1 and 2 respectively, gives different 'volume'), and delay2 is 1. I replicated exactly the same, as I wanted to have the same sound.

These engines (SpecialFX, Music Synth and so on) are all based on the same principle of playing with the duty cycle, i.e. the 0/1 balance of a period, on a small enough scale where modifying the cycle is still perceived more as a change in volume rather than the timbre. The reason they employ this two-part delay scheme is reducing volume-dependent timing fluctuations/cross detune. One delay counter is decreased while the other one is increased at the same time as the envelope decays. This allows the length of the pulse to remain the same throughout regardless of volume, so that whichever cross-detune issues remain are frequency related.

Well said, my friend. That's indeed one of the reasons I'm hooked on 1-bit music. There's a lot of uncharted territory waiting to be explored.