[MZ-700] IN-GAME 1-bit PWM

I am currently experimenting with an approach to create a volume effect. Instead of emitting a high or low signal with 100% duty every ISR, I have introduced (partially for the moment) the notion of 4-bit PCM instead of 1-bit PCM. Well, I realized that the mode 0 allowed me to create a low and then a high signal with a "programmable" duty. Indeed, as soon as the counter reaches the threshold, it switches to the high signal and stays there until the counter is reprogrammed.

So I thought I could have fun creating a 4-bit PCM with duties like this : 0/15, 1/15, 2/15, ..., 14/15, 15/15. Indeed with 1/15, the volume seems much lower.

Now the technique (and why only 4-bit PCM):

Instead of a 256-byte page containing the mode programming bytes of counter 0 (used for the production of its square to 1.108404688 MHz), I determine two contiguous tables. The first one continues to play the same role but indirectly because it contains indexes on the second page which contains code every 16 bytes to produce a square signal with a duty related to the index of the period of an ISR (one every 3.902825 KHz)

Here is the definition of the two pages:

    align 256
sfx_buffer:
        DS        256,$00
sfx_play_pwm_0:
        LD        HL,$E007 ; duty 0% !
        LD        (HL),$28
        JP        sfx_isr_ret
    align 16
sfx_play_pwm_1_15:
        LD        HL,$E007 ; 16-bit counter, duty 6,6...%
        LD        (HL),$30
        LD        L,$04
        LD        (HL),SFX_DUTY_1_15>>0
        LD        (HL),SFX_DUTY_1_15>>8
        JP        sfx_isr_ret
    align 16
...
sfx_play_pwm_14_15:
        LD        HL,$E007 ; 16-bit counter, duty 93,3...%
        LD        (HL),$30
        LD        L,$04
        LD        (HL),SFX_DUTY_14_15>>0
        LD        (HL),SFX_DUTY_14_15>>8
        JP        sfx_isr_ret
    align 16
sfx_play_pwm_15:
        LD        HL,$E007 ; duty 100% !
        LD        (HL),$20
        JP        sfx_isr_ret

I took 4-bit index because I only have 2 bytes left for the 1/15 to 14/15. By switching to 5-bit, I wouldn't be able to fit all the duties in one page of code.

Now I have to adapt the ISR :

sfx_isr:    PUSH    HL
        PUSH    AF
        
        LD        HL,$E006 ; rearm counter to get the next ISR
        LD        (HL),PIT_CNT2
        
        LD        HL,sfx_buffer ; current index stored in the first page
sfx_isr_buffer_index equ $-2
        LD        L,(HL) ; read a byte $i0 where i is the index
        INC        H ; go to the next page
        JP        (HL) ; jump to the code emitting a square signal with the right duty 

sfx_isr_ret:        
        LD        HL,sfx_isr_buffer_index ; next index for the next ISR

sfx_isr_on_off:
        NOP ; either $34 (INC [HL]) when playing is ON or $00 (NOP) if OFF

        POP        AF
        POP        HL

        EI
        RET

The ISR initially had 114 execution cycles. Here we have 115 cycles to which we must add either 30 cycles or 57 cycles depending on the desired duty: 145 or 172 cycles. The game always seems to run at 50 fps.

The reason I wanted to do this is twofold:

- to see if by this set of duty, we could create a volume effect and thus have the possibility to mix several sources.
- to test the possibility to make "intersective" PWM : https://en.wikipedia.org/wiki/Pulse-width_modulation.

I'm not confident to build a tracker to generate those bytes so for now I used the pcm2pmw v1 tool (https://github.com/JeffAlyanak/pcm2pwm) in the 1-bit PCM case. I need to write a tool to encode a wave file into a 4-bit PCM using intersective PWM encoding.

Obviously WAV or MP3 bitstreams are too big to encode into bytes playable by the game. I don't know if I will use that player for music background or just for game sound effects.

Oh that! I used an emulator (my stock MZ-700 needs to be repaired). Due to the fact I need to use Audacity to amplify a wave stream extremely and to resample it to 3902.8314Hz to transform into a "1-bit PCM" wav file, It is not satisfying as it is very saturated.

I used that MP3 as source: Learn Soundation - Chip Music - Square Wave.mp3.

I made an horrible resampling of it: Sampler.wav.

And it sounds as such when playing SpaceRallyTest.mp4.

Be sure to lower the volume.

Great to see some in-game 1-bit music action, and also great to see the MZ-700 getting some love! Tbh I think it actually sounds surprisingly decent considering the sample rate.

There are some people on here that know more about 8253 wizardry than me, but a quick couple of thoughts:

- Beware of the Nyquist limit, ie. the highest frequency in the audio may at most be half of the sample rate. So if you replay at ~2Khz, you should apply a low-pass filter with a cutoff of ~1KHz before resampling.
- pcm2pwm isn't very well suited for harmonic content. Its main purpose is to encode percussive sounds in a very size-efficient manner.
- I'm not sure intersective PWM is worth it. In order to produce decent results, it requires a very high sample rate (likely at least 80KHz), which would be pretty hard to pull off on a 3.5MHz Z80 machine.
- It is possible to mix multiple channels without volume control. A method that works well at low sample rates is to have 2-4 pulse wave generators with a duty cycle below ~25%, and OR their outputs together (example).

Anyway, thanks for the detailed write-up, looking forward to hearing more from your 1-bit endeavours!

Ah, now I understand a bit better how you want to generate the different volume levels.

2) You can specify high/low thresholds for pcm2pwm, ie.

$ pcm2pwm sound.wav hi lo

where hi and lo are 8-bit unsigned integers. Default is hi=252, lo=3. Lowering hi and raising lo will make the converter more sensitive.

3) To get rid of the parasite tone (3903Hz), mixing frequency would need to rise above the audible range. So ideally you'd mix at 20KHz or more. On Spectrum we usually mix around 15KHz, and rely on hardware filtering/smoothing to take care of any remaining noise/whining. Beware that emulators introduce additional noise, depending on how they implement sound. MAME's MZ-700 suffers from this, for example.
4). Let me try to construct a basic example. Late night coding attempt, and completely untested, but the idea is to do something like this:

; two-channel OR mixing (aka Squeeker method)
  ld hl,0        ; reset oscillator 2 state
  ld de,div2     ; osc2 clock [freq = sample_rate * div2 / $10000]
  exx
  ld hl,0        ; reset osc1 state
  ld de,div1     ; osc1 clock
  ld bc,ring_buffer   ; must be aligned to 256b page
  
loop
  add hl,de      ; update osc counter channel 1
  ld a,h
  add a,$e0      ; $100 - duty ($e0 = 12.5%)
  ld a,$27
  adc a,0        ; if duty threshold exceeded, A is now $28 
  exx
  add hl,de      ; same for channel 2
  ld c,a
  ld a,h
  add a,$e0
  ld a,0
  adc a,c        ; A is now $27, $28, or $29
  exx
  and #28        ; mask bits, A = $20 | $28
  ld (bc),a
  inc c
  jr z,loop

PS: You should be able to change your nick now. Let me know if it doesn't work, then I'll change it for you.