ld a,MAGIC_NUM
  add a,e
  rrca
  xor d
  ld e,a
  inc d

For MAGIC_NUM, most values do pretty much the same, except some that are straight metallic beeps and a few that sound more rumbly.
test.tap plays through all possible values.

The main downside is that we can't smc-hotswap this with regular tone channel code. What could work though is to hotswap it on an 8-bit divider and use a separate 8-bit pre-scale on this. Pre-scale would pitch the noise as well. Unfortunately the perceived pitch of the noise is quite a bit lower than using add hl,de; rlc h. Not sure if it's actually much of an improvement over just lazily reading from ROM:

  ld a,(de)
  inc de

From the article Grayscale on 1-bit LCDs:

"To be honest, I didn’t come to this stage by accident, I have worked with delta-sigma modulators and noise shapers in audio applications before so I know these, and I have been wondering about if they could be applied to driving these LCDs for a long time."

Don't think it was me who invented the rla trick. I'd be a cheap bastard and omit both the rla and the sbc a,a. Doing that could potentially open up a few more possibilities here, but with the unrolled loop, modifying 3 bytes might not be worth it. Even without that, I've got a feeling there are more possibilities hiding in those 2 bytes. I just don't see them right now. #dd 0 0 would give a pin pulse, of course, but that's probably not very useful in this setup. You could also swap bc and sp. Then #dd 0, add b/c would give duty control for example, but we already have that via phase offset, of course.

Oh yeah, dithering applied to the 1-bit sound synthesis may bring some quite interesting results! Cool idea, never thought about that.

Excuse me for having a brain freeze right now, but what is the purpose of the rla in normal phasing mode?

Some tangentially related, inspirational reading: Grayscale on 1-bit LCDs. Would be interesting to try and apply some of the more advanced techniques to 1-bit music. Iirc perevalovds was using error diffusion of sorts for 1-bit sampling.

Regular XOR/OR/AND modes in Phaser3 were:

    add hl,bc
    ld a,h
    add ix,sp
    xor/and/or ixh
    rla
    sbc a,a
    and 16
    out (#fe),a

Now, instead of xor ixh:rla we can do more by changing just two bytes - keeping the ix/iy prefix in place:

cp ixh:nop - the CrossPhase
adc a,ixh:add a,h - fat octaving noisy timbre
xor ixh:sub h - more noise in a similar timbre
xor ixh:sub l - very noisy yet still tonal timbre
xor ixl:sub h - periodic noise of one kind
xor ixl:sub l - periodic noise of another kind

And another cool thing is that Phaser3 unrolls the sound loop 4 times for pseudo volume effects. And we're not obliged to use the same 'algorithm' in each iteration, we can mix in any 4, getting even more weird timbres.

I've used the idea behind ModPhase (without the xor modulation) a couple of places, BetaPhase for example. The good thing is that it can be done in the outer loop, which also allows for variable speed (by adding a variable amount to DE). In a pinch, one could even abuse the outer length counter for this, hehe.

    ld hl,0
    ld bc,100
    exx
    ld hl,0
    ld bc,201
    
loop

    add hl,bc
    ld a,h
    exx
    add hl,bc
    cp h
    exx
    sbc a,a
    and 16
    out (#fe),a

    jp loop

bc=100, bc'=100+detune is the regular PWM like drift, bc=100, bc'=bc*2+detune is one with octave etc, bc'=bc*4+detune is another octave, etc. Other not related values is kinda Earth Shaker'y, but not so much, a different kind of the sound.

Edit: I tested it out, and it actually matches exactly to Phaser1 in the resulting sound for any given adders I thought to test. Interesting.

Re-Edit: Nah, I messed up the previous test (was testing it inside Ear Shaver EX framework, and used a wrong pointer). It is really different both from EarthShaker and Phaser1! Hence giving this potential engine a name of CrossPhase, will add it as an Ear Shaver EX's update for now.

    di
    ld hl,0
    ld de,0
    ld bc,#180
    ld sp,#38+#180/4

.play_note
    add hl,bc

    ex de,hl
    add hl,sp
    ccf
    sbc a,a
    ex de,hl
    and h
    ld h,a

    cp #20
    sbc a,a
    out (#fe),a

    dec ixl
    jr nz,.play_note
    dec bc
    jr .play_note

Not going to pretend I have any idea what's going on here. Some interesting sounds happening though. Seems that the note frequency is actually determined by the value in sp, not the one in bc. Just resetting the phase without additional modulation in the outer loop does something rather Earth Shaker-y. inc sp instead of dec bc is fun, too. No idea how to make any practical use of all of this, though.

Not that it is useless anyways, but to make it usable from composer standpoint it is better to find a way to provide the secondary divider in a form better than a 0..65535 value per note.